您当前的位置：首页 > 电子 > 机器人与智能物联

智能小车实践教程

时间：03-16来源：作者：点击数：
前言

先前做了一个外包app关于google的blockly二次开发，文见Android 基于Android blockly和蓝牙通信的机器人编程APP，于是乎对于硬件方面也产生了一些兴趣，自己实现了软件，但是硬件还不太懂，于是乎开始学习研究一下硬件方面的知识，也打算自己做一个智能小车。

如果你也是个软件开发者，也希望自己多少能懂一点硬件知识，软硬兼修的话，可以跟着我一起也来制作一个智能小车。期间会遇到很多硬件相关的术语或者专有名词，优秀的你，肯定会不懂就查不懂就学的，这是最重要的过程。

先上图
有点丑 线太多了 有条件的可以绑起来
底面
斜面
侧面
需要实现的功能

1、蓝牙控制小车的行进

2、小车的速度可调

3、超声波避障

4、循迹

准备硬件材料

我这里花了点时间把之前的采购清单整理了一下，我当时找了很多家店，那家的比较便宜，分享给大家，不是打广告，只是为了让大家省点钱。（当时前后购买了好几次，运费给了不少，这里大家可以一次性买清）

1、红外循迹传感器 4个 [https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=43751274135&_u=aldqfnla542]

2、BLE蓝牙hc-08（带引脚）[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=36426439097&_u=aldqfnl3d00]

3、arduino uno [https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=525462013769&_u=aldqfnl5f3a]

4、智能小车底盘及其轮子 [https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=43735291557&_u=aldqfnl41dc]

5、L298n电机驱动模块[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=521709080904&_u=aldqfnl6aaa]

6、超声波测距模块[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=555002408091&_u=aldqfnlb0d6]

7、杜邦线 10cm 20cm 30cm 和 母对母 母对公 公对公 每样一排40根 [https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=546979596255&_u=aldqfnla016]

8、18950电池盒[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=521746780501&_u=aldqfnl8b94]

9、铜柱 各类长短 带头的 不带头的 都来个10根吧[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=558741728111&_u=aldqfnl0dc7]

10、螺丝 螺帽 若干 多数是3mm的 其他的也可以买点 15根+吧[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=521771839187&_u=aldqfnl2beb]

11、螺丝刀[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=521703689593&_u=aldqfnlead1]

12、mini面包板[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=521761502825&_u=aldqfnl6f02]

13、黑色电工胶带[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=521702965521&_u=aldqfnle13c]

14、sg90舵机[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=43792233123&_u=aldqfnl3bf5]

15、hr-sr04超声波模块支架[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=521750109177&_u=aldqfnlf46b]

16、小电钻（可选）[https://item.taobao.com/item.htm?spm=a1z09.2.0.0.5b4e2e8dE025fh&id=521708346105&_u=aldqfnlac59]

17、充电电池18650 3.7v 2只（我这里是神火，较贵，可买其他的 注意:3.7v的 普通超市是没有的，不是一般的7号或者5号电池 ）[https://item.jd.com/5171888.html]

18、充电器[https://item.jd.com/4284307.html]

组装小车

成型图：（多图预警！！！）

介绍图

1、首先按照小车的说明书把小车的马达和轮子都依次装上去，如图

2、然后把买来的杜邦线，可以直接拔掉接头，露出线

使用杜邦线 如图和马达连接

3、然后接线，左边两排的马达会有连接，右边两排的马达会有连接。注意，这里我们先按照如图所示的方法接线。

马达上面的接口线和另一个马达下面的接口线 接在一起
如图

4、第一层底盘底部装上3个循迹用的红外传感器，依次排列，9根线

现在装，是因为，如果后面盖上了上层底盘，就不太好装了

装上之后，第一层底盘的东西就装的差不多了

如图

5、第二层底盘上部，装上电池盒

现在装，是因为，如果后面盖上了上层底盘，就不太好装了

6、第二层底盘上部，装上舵机。这里使用到了，舵机支架和舵机，有点不太好装，耐心一点

现在装，是因为，如果后面盖上了上层底盘，就不太好装了

7、把两层底盘合并起来，OK，大功告成！！！！鼓掌👏

最终如图

这下小车就算拼装好了

ps: 这样一次性装好，可以避免多次的拆装底盘（我就是拆了好多次，好费神）

小车启动

小车装好了，激动了一会儿，但是还不能动，现在就要让它能跑起来

跑起来的话，我们需要使用：电机驱动、电池、arduino的板子

先简单介绍一下电机驱动：

电机驱动
  • 电机1接口 out1 out2 和 电机2接口out3 out4用于和马达的交互，原理就是，给马达的高低电平的不同，使得马达往前转动还是往后转动
  • 供电正极：可接受5-12v的电压，和电池盒接在一起，两个3.7v的电池7.4伏，够用
  • 地线：和电池盒的地线、arduino的地线连在一起
  • 5v：连接arduino的电源线
  • ENA、ENB：调速用的，默认情况下，有个盖子，盖起来的，相当于直接连接，满压5v就代表全速。后面会接arduino的pwm接口，来调速
    -In1~4: 接在arduino上

接入如图：

1、把马达对应的 4个线接入到电机的out1 out2 out3 out4口，

注意对照一下前面接线的颜色，顺序暂时可是弄成跟我的一样（因为后面arduino的代码里面要一致）

2、连接电池盒与电机（一般我们认为 红色是电源、黑色为地线），连接arduino与电机

3、连接电机的in1-4口和arduino的19、18、17、16（有人问是哪里，A0~A5其实分别对应的是14-19）

示意图：

连接好，装上电池，接下来解释，写arduino的程序了

1、去官网下载编译器

长这样，我是mac的，不过操作方法都差不多

2、通过电源接口连接到电脑

选择这个uno

连接成功之后就有自己板子的信息了，如果没有的话，去网上查一下，下载对应操作系统的arduino的驱动就好

3、代码

这里我们就简单的让小车 循环前后左右动。

#include <Servo.h>
//定义五中运动状态
#define STOP      0
#define FORWARD   1
#define BACKWARD  2
#define TURNLEFT  3
#define TURNRIGHT 4
//定义需要用到的引脚
int leftMotor1 = 16;
int leftMotor2 = 17;
int rightMotor1 = 18;
int rightMotor2 = 19;

void setup() {
  // put your setup code here, to run once:
  //设置控制电机的引脚为输出状态
  pinMode(leftMotor1, OUTPUT);
  pinMode(leftMotor2, OUTPUT);
  pinMode(rightMotor1, OUTPUT);
  pinMode(rightMotor2, OUTPUT);
}

void loop() {
  // put your main code here, to run repeatedly:
  int cmd;
  for(cmd=0;cmd<5;cmd++)//依次执行向前、向后、向左、想有、停止四个运动状态
  {
    motorRun(cmd);  
    delay(2000);//每个命令执行2s 
  } 
}
//运动控制函数
void motorRun(int cmd)
{
  switch(cmd){
    case FORWARD:
      digitalWrite(leftMotor1, LOW);
      digitalWrite(leftMotor2, HIGH);
      digitalWrite(rightMotor1, LOW);
      digitalWrite(rightMotor2, HIGH);
      break;
     case BACKWARD:
      digitalWrite(leftMotor1, HIGH);
      digitalWrite(leftMotor2, LOW);
      digitalWrite(rightMotor1, HIGH);
      digitalWrite(rightMotor2, LOW);
      break;
     case TURNLEFT:
      digitalWrite(leftMotor1, HIGH);
      digitalWrite(leftMotor2, LOW);
      digitalWrite(rightMotor1, LOW);
      digitalWrite(rightMotor2, HIGH);
      break;
     case TURNRIGHT:
      digitalWrite(leftMotor1, LOW);
      digitalWrite(leftMotor2, HIGH);
      digitalWrite(rightMotor1, HIGH);
      digitalWrite(rightMotor2, LOW);
      break;
     default:
      digitalWrite(leftMotor1, LOW);
      digitalWrite(leftMotor2, LOW);
      digitalWrite(rightMotor1, LOW);
      digitalWrite(rightMotor2, LOW);
  }
}

OK，不出意外的话，你的小车也可以动起来啦！！！！鼓掌👏

代码解析：

 case FORWARD:
      digitalWrite(leftMotor1, LOW);
      digitalWrite(leftMotor2, HIGH);
      digitalWrite(rightMotor1, LOW);
      digitalWrite(rightMotor2, HIGH);
      break;

可以看到 前进的时候，我们把引脚leftMotor1设置为了低电压，leftMotor2设置为了高电压

有人会问为啥 从图上看，为啥两个马达的 高低电压 不同，却是相同的方向。那是因为，这两个马达 是这样放的。

如果是你把后面那个摆成跟前面那个一样，后面的下上就变成了上下，其实上下的高低电压就一致了。所以，前后轮的转动方向就一致了（这里根据我们的接线方法 我们是前进，如果说接线方法不同或者接反了，可以把代码里面的LOW和HIGH进行互换）

转弯：

我们这里的行为方式是跟坦克类似的，因为我们没有转向轮。

如果想要左转，就是左边轮子向后，右边轮子向前。这样的话会是，原地的左转；如果想要，向左转弯，保持前进的话，就应该是，左边保持低速前进，右边保持高速前进；如果想要调整原地转动的速率和转幅，可以调整左轮的速度和右轮的速度差值来实现。后面的蓝牙小车调速会讲到。

右转也是同理。

蓝牙小车
我们会用到4个引脚

接线方法：

TX：接Arduino UNO开发板”RX”引脚

RX：接Arduino UNO开发板”TX”引脚

GND：接Arduino UNO开发板”GND”引脚

VCC：接Arduino UNO开发板”5V”或”3.3V”引脚

示意图

这里，我们使用到了调速功能，因为前面说到我们如果想要前进转弯，就需要设置左右两排轮子不同的速度来实现。这里需要电机驱动接入ENA ENB的引脚接口到arduino的PWM接口（arduino上面的引脚号码前有~的就是PWM接口，这里我们使用5、6）。

示意图
写入代码注意！：

我们这里如果接入了蓝牙的RXD、TXD的时候，如果想要连接arduino和电脑进行代码写入，是不行的。因为，如果蓝牙占用了RXD和TXD，没有办法写入了。拔掉一个，然后就可以了。

代码：

#include <Servo.h>


//定义五中运动状态
String STOP    =  "D105FFFF";

String UP  = "D101FFFF";
String DOWN = "D102FFFF";
String LEFT = "D103FFFF";
String RIGHT = "D104FFFF";

String LEFT_UP  = "D111FFFF";
String LEFT_DOWN = "D112FFFF";
String RIGHT_UP = "D113FFFF";
String RIGHT_DOWN = "D114FFFF";

//定义需要用到的引脚
int leftMotor1 = 16;
int leftMotor2 = 17;
int rightMotor1 = 18;
int rightMotor2 = 19;

int leftPWM = 5;
int rightPWM = 6;

int inputPin = 7; // 定义超声波信号接收接口
int outputPin = 8; // 定义超声波信号发出接口

String comdata = "";

void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);
  //设置控制电机的引脚为输出状态
  pinMode(leftMotor1, OUTPUT);
  pinMode(leftMotor2, OUTPUT);
  pinMode(rightMotor1, OUTPUT);
  pinMode(rightMotor2, OUTPUT);
  //超声波控制引脚初始化
  pinMode(inputPin, INPUT);
  pinMode(outputPin, OUTPUT);
  //调速
  pinMode(leftPWM, OUTPUT);
  pinMode(rightPWM, OUTPUT);
}

void loop() {
  while (Serial.available() > 0)
  {
    int i = Serial.read();
    char c = char(i);
    comdata += c;  //每次读一个char字符，并相加
    delay(2);
  }

  if (comdata.length() > 0) {
    Serial.println(comdata); //打印接收到的字符
    motorRun(comdata, 250);
    comdata = "";
  }
}

//运动控制函数
void motorRun(String cmd, int value)
{
  analogWrite(leftPWM, value);  //设置PWM输出，即设置速度
  analogWrite(rightPWM, value);
  if (cmd == UP) {
    Serial.println("UP");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == DOWN) {
    Serial.println("DOWN");
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else  if (cmd == LEFT) {
    Serial.println("left");
    analogWrite(leftPWM, value - 90); //设置PWM输出，即设置速度
    analogWrite(rightPWM, value - 70);
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else  if (cmd == RIGHT) {
    Serial.println("right");
    analogWrite(leftPWM, value - 70); //设置PWM输出，即设置速度
    analogWrite(rightPWM, value - 90);
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == LEFT_UP) {
    analogWrite(leftPWM, value - 150); //设置PWM输出，即设置速度
    Serial.println("LEFT_UP");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == LEFT_DOWN) {
    Serial.println("LEFT_DOWN");
    analogWrite(leftPWM, value - 150); //设置PWM输出，即设置速度
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else  if (cmd == RIGHT_UP) {
    analogWrite(rightPWM, value - 150); //设置PWM输出，即设置速度
    Serial.println("RIGHT_UP");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == RIGHT_DOWN) {
    analogWrite(rightPWM, value - 150); //设置PWM输出，即设置速度
    Serial.println("RIGHT_DOWN");
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else {
    Serial.println("stop");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, LOW);
  }
}

代码解析：

  • 这里我们为了可以直接使用我自己的app，所以把指令直接定义为了和我app里面一样的。APP下载地址
  • 一共有9个指令，这里的app里面对于小车行进做了两种操作。一种是上下左右停，一种是摇杆（其实就是 上下左右 左上 右上 左下 右下）。如图：
    上下左右
摇杆
  analogWrite(leftPWM, value);  //设置PWM输出，即设置速度
  analogWrite(rightPWM, value);

是左右两边轮子的调速代码

  • 默认我们的对于PWM写入的最大速度值为255，按道理区间为1-255，但是，经过测试发现（根据不同电池情况），如果低于一定值的，就带不动马达转动了（我这里大约是100左右，如果电池没电了可能最小值更高）
  • 原地左转
  } else  if (cmd == LEFT) {
    Serial.println("left");
    analogWrite(leftPWM, value - 90); //设置PWM输出，即设置速度
    analogWrite(rightPWM, value - 70);
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);

这里我的左转，我不想让它原地的转动的转幅太大，所以我调小了两边的转速

  • 左前
  } else  if (cmd == LEFT_UP) {
    analogWrite(leftPWM, value - 150); //设置PWM输出，即设置速度
    Serial.println("LEFT_UP");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);

这里，你会发现“左前”，其实代码是在“前进”的代码基础上加了一句调速代码，如我们先前所说，我们要保持前进的同时转弯，就需要向前，并且减速左边的轮子，就可以实现了。

ok，写入了代码，接好RX TX线，装上电池，就可以运行了。蓝牙的蓝色的灯也会亮起来。

成型图

这时候，可以使用下载好的app来连接蓝牙小车了。连接成功之后，就可以通过控制界面的两种控制方式来控制我们的小车啦！！！不出意外的话，鼓掌👏！！

超声波避障

超神波避障的主要原理：

利用超声波测距传感器测量小车与障碍之间的距离，小于一定值的时候就停下，然后利用舵机来改变超声波传感器的方向继续测距，如果哪边没有障碍，就往哪边转向来避开障碍，然后再前进。

我们这里需要用到的就是舵机和超声波传感器（及其支架）。舵机，之前装底盘的时候就装上去了，如果那时候没有装的话，现在要装的话就比较困难了。

插线：

  • 超声波有4个引脚，vcc、trig、echo、gnd，vcc和gnd插到arduino上，但是，现在来看，arduino上面已经没有足够的 vcc和gnd的引脚口了，所以，我们要利用 mini面包板来 扩展一些。
mini面包板

扩展原理：

示意图

这样连接的话，一竖排都是相当于是vcc或者gnd线的接口。

  • trig和echo分别接到arduino的“8、7”号引脚上面(“Trig”引脚控制超声波发出声波，对应int outputPin=8; “Echo”引脚反应接收到返回声波，对应int inputPin=7;)。大致原理就是 发送一个超声波，然后接受一个超声波，然后通过时间来算得距离
  • 舵机一般为三根线：灰色——GND，红色——VCC，橙色——控制信号。因此我们将灰色色线接到GND，红色线接到“+5V”引脚，橙色线接到“9”号引脚
成型图
成型图
示意图

代码：

#include <Servo.h>


//定义五中运动状态
String STOP    =  "D105FFFF";

String UP  = "D101FFFF";
String DOWN = "D102FFFF";
String LEFT = "D103FFFF";
String RIGHT = "D104FFFF";

String LEFT_UP  = "D111FFFF";
String LEFT_DOWN = "D112FFFF";
String RIGHT_UP = "D113FFFF";
String RIGHT_DOWN = "D114FFFF";


#define BIZHANG_START "D301FFFF"
#define BIZHANG_END "D302FFFF"

#define PIN_SERVO 9  //舵机信号控制引脚

//定义需要用到的引脚
int leftMotor1 = 16;
int leftMotor2 = 17;
int rightMotor1 = 18;
int rightMotor2 = 19;

int leftPWM = 5;
int rightPWM = 6;

int inputPin = 7; // 定义超声波信号接收接口
int outputPin = 8; // 定义超声波信号发出接口

Servo myServo;  //舵机

String lastCmd;

String comdata = "";

void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);
  //舵机引脚初始化
  myServo.attach(PIN_SERVO);
  //设置控制电机的引脚为输出状态
  pinMode(leftMotor1, OUTPUT);
  pinMode(leftMotor2, OUTPUT);
  pinMode(rightMotor1, OUTPUT);
  pinMode(rightMotor2, OUTPUT);
  //超声波控制引脚初始化
  pinMode(inputPin, INPUT);
  pinMode(outputPin, OUTPUT);
  //调速
  pinMode(leftPWM, OUTPUT);
  pinMode(rightPWM, OUTPUT);
}

void loop() {
  while (Serial.available() > 0)
  {
    int i = Serial.read();
    char c = char(i);
    comdata += c;  //每次读一个char字符，并相加
    delay(2);
  }

  if (comdata.length() > 0) {
    Serial.println(comdata); //打印接收到的字符
    if (comdata == BIZHANG_START) {
      avoidance();
    } else if (comdata == BIZHANG_END) {
      motorRun(STOP, 250);
    } else {
      motorRun(comdata, 250);
    }
    lastCmd = comdata;
    comdata = "";
  } else {
    if (lastCmd == BIZHANG_START) {
      Serial.println("现在是 避障");
      avoidance();
    }
  }
}

void avoidance()
{
  int pos;
  int dis[3];//距离
  motorRun(UP, 255);
  myServo.write(90);
  dis[1] = getDistance(); //中间
  Serial.println("mid dis:" + dis[1]);
  if (dis[1] < 30)
  {
    motorRun(DOWN,255);
    delay(300);                                                                                                                                                                           motorRun(STOP, 0);
    for (pos = 90; pos <= 150; pos += 1)
    {
      myServo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(10);                       // waits 15ms for the servo to reach the position
    }
    dis[2] = getDistance(); //左边
    Serial.println("left dis:" + dis[2]);
    for (pos = 150; pos >= 30; pos -= 1)
    {
      myServo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(10);                       // waits 15ms for the servo to reach the position
      if (pos == 90)
        dis[1] = getDistance(); //中间
      Serial.println("mid dis:" + dis[1]);
    }
    dis[0] = getDistance(); //右边
    Serial.println("right dis:" + dis[0]);
    for (pos = 30; pos <= 90; pos += 1)
    {
      myServo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(10);                       // waits 15ms for the servo to reach the position
    }
    if (dis[0] < dis[2]) //右边距离障碍的距离比左边近
    {
      //左转
      motorRun(LEFT, 250);
      delay(500);
    }
    else  //右边距离障碍的距离比左边远
    {
      //右转
      motorRun(RIGHT, 250);
      delay(500);
    }
  }
}

int getDistance()
{
  digitalWrite(outputPin, LOW); // 使发出发出超声波信号接口低电平2μs
  delayMicroseconds(2);
  digitalWrite(outputPin, HIGH); // 使发出发出超声波信号接口高电平10μs，这里是至少10μs
  delayMicroseconds(10);
  digitalWrite(outputPin, LOW); // 保持发出超声波信号接口低电平
  int distance = pulseIn(inputPin, HIGH); // 读出脉冲时间
  distance = distance / 58; // 将脉冲时间转化为距离（单位：厘米）
  Serial.println("distance:" + distance); //输出距离值

  if (distance >= 50)
  {
    //如果距离小于50厘米返回数据
    return 50;
  }//如果距离小于50厘米
  else
    return distance;
}


//运动控制函数
void motorRun(String cmd, int value)
{
  analogWrite(leftPWM, value);  //设置PWM输出，即设置速度
  analogWrite(rightPWM, value);
  if (cmd == UP) {
    Serial.println("UP");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == DOWN) {
    Serial.println("DOWN");
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else  if (cmd == LEFT) {
    Serial.println("left");
    analogWrite(leftPWM, value - 90); //设置PWM输出，即设置速度
    analogWrite(rightPWM, value - 70);
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else  if (cmd == RIGHT) {
    Serial.println("right");
    analogWrite(leftPWM, value - 70); //设置PWM输出，即设置速度
    analogWrite(rightPWM, value - 90);
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == LEFT_UP) {
    analogWrite(leftPWM, value - 150); //设置PWM输出，即设置速度
    Serial.println("LEFT_UP");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == LEFT_DOWN) {
    Serial.println("LEFT_DOWN");
    analogWrite(leftPWM, value - 150); //设置PWM输出，即设置速度
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else  if (cmd == RIGHT_UP) {
    analogWrite(rightPWM, value - 150); //设置PWM输出，即设置速度
    Serial.println("RIGHT_UP");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == RIGHT_DOWN) {
    analogWrite(rightPWM, value - 150); //设置PWM输出，即设置速度
    Serial.println("RIGHT_DOWN");
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);   
    digitalWrite(rightMotor2, HIGH);
  } else {
    Serial.println("stop");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, LOW);
  }
}
代码解析：

超声波：

  1. 采用Trig引脚触发，给至少10us的高电平脉冲信号
  2. 模块自动发送8个40kHz的方波，自动检测是否有信号返回
  3. 有信号返回，通过Echo引脚输出一个高电平脉冲，高电平脉冲持续的时间就是超声波从发射到反射返回的时间。距离=(高电平脉冲时间*340)/2。（声音在空气中传播速度为340m/s）

超声波发出引脚“Trig”为高时对外发出超声波，为保证发出10μs声波，因此在发送之前需要将该引脚拉低，并给他一定反应时间。

digitalWrite(outputPin, LOW); // 使发出发出超声波信号接口低电平2μs
delayMicroseconds(2);

之后发送10μs超声波

digitalWrite(outputPin, HIGH); // 使发出发出超声波信号接口高电平10μs，这里是至少10μs

声波发送之后禁止其继续发送，同时开始检测是否反射回来的声波

digitalWrite(outputPin, LOW); // 保持发出超声波信号接口低电平
  int distance = pulseIn(inputPin, HIGH); // 读出脉冲时间

pulseIn()单位为微秒，声速344m/s，所以距离cm=344100/1000000pulseIn()/2约等于pulseIn()/58.0

distance= distance/58; // 将脉冲时间转化为距离（单位：厘米）

超声波模块工作受物体表面反射程度影响，并且在传播过程中信号强度容易衰减，因此该模块适用的检测距离有限，一般在50cm以内相对正确，而且我们在避障时不需要检测太远的距离，因此超过50cm以上的都按50cm计算

舵机：

 dis[1] = getDistance(); //中间
  Serial.println("mid dis:" + dis[1]);
  if (dis[1] < 30)
  {
    motorRun(DOWN,255);
    delay(300);                                                                                                                                                                           motorRun(STOP, 0);
    for (pos = 90; pos <= 150; pos += 1)
    {
      myServo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(10);                       // waits 15ms for the servo to reach the position
    }
    dis[2] = getDistance(); //左边
    Serial.println("left dis:" + dis[2]);
    for (pos = 150; pos >= 30; pos -= 1)
    {
      myServo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(10);                       // waits 15ms for the servo to reach the position
      if (pos == 90)
        dis[1] = getDistance(); //中间
      Serial.println("mid dis:" + dis[1]);
    }
    dis[0] = getDistance(); //右边
    Serial.println("right dis:" + dis[0]);
    for (pos = 30; pos <= 90; pos += 1)
    {
      myServo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(10);                       // waits 15ms for the servo to reach the position
    }
    if (dis[0] < dis[2]) //右边距离障碍的距离比左边近
    {
      //左转
      motorRun(LEFT, 250);
      delay(500);
    }
    else  //右边距离障碍的距离比左边远
    {
      //右转
      motorRun(RIGHT, 250);
      delay(500);
    }

先获取中间时候的距离，小于30之后停下。向左边转60度左右，然后到达最左边的时候，获取左边的距离，然后转动到中间获取中间的距离，然后转动到右边，获取右边的距离。

比较左右边距离，哪边长小车就往哪边 转动，然后继续向前。

ok，如果线接好了、代码录入了，装上电池就可以使用app的避障，“开始”和“结束”按钮，来运行了。

不出意外，你的小车就有了简单的避障功能了。故障👏！！！

ps：利用超声波避障，总会有些不太精准的情况，比如障碍不是一个较为平整的能够被很好测算距离的情况。总之，我们追求的是过程，过程最重要嘛。

循迹

循迹的话由于循迹算法比较粗糙，有时候会有一些小问题，比如冲出黑线区域等。所以这里，简单的介绍一下。

上一下所有的代码
#include <Servo.h>


//定义五中运动状态
String STOP    =  "D105FFFF";

String UP  = "D101FFFF";
String DOWN = "D102FFFF";
String LEFT = "D103FFFF";
String RIGHT = "D104FFFF";

String LEFT_UP  = "D111FFFF";
String LEFT_DOWN = "D112FFFF";
String RIGHT_UP = "D113FFFF";
String RIGHT_DOWN = "D114FFFF";


#define BIZHANG_START "D301FFFF"
#define BIZHANG_END "D302FFFF"
#define XUNJI_START "D201FFFF"
#define XUNJI_END "D202FFFF"

#define PIN_SERVO 9  //舵机信号控制引脚

//定义需要用到的引脚
int leftMotor1 = 16;
int leftMotor2 = 17;
int rightMotor1 = 18;
int rightMotor2 = 19;

int follow1 = 10;
int follow2 = 11;
int follow3 = 12;

int leftPWM = 5;
int rightPWM = 6;

int inputPin = 7; // 定义超声波信号接收接口
int outputPin = 8; // 定义超声波信号发出接口

int xunjiSpeed = 170;

Servo myServo;  //舵机

String lastCmd;

String comdata = "";

void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);
  //舵机引脚初始化
  myServo.attach(PIN_SERVO);
  //设置控制电机的引脚为输出状态
  pinMode(leftMotor1, OUTPUT);
  pinMode(leftMotor2, OUTPUT);
  pinMode(rightMotor1, OUTPUT);
  pinMode(rightMotor2, OUTPUT);
  //超声波控制引脚初始化
  pinMode(inputPin, INPUT);
  pinMode(outputPin, OUTPUT);
  //调速
  pinMode(leftPWM, OUTPUT);
  pinMode(rightPWM, OUTPUT);
  //寻迹模块引脚初始化
  pinMode(follow1, INPUT);
  pinMode(follow2, INPUT);
  pinMode(follow3, INPUT);
}

void loop() {
  while (Serial.available() > 0)
  {
    int i = Serial.read();
    char c = char(i);
    comdata += c;  //每次读一个char字符，并相加
    delay(2);
  }

  if (comdata.length() > 0) {
    Serial.println(comdata); //打印接收到的字符
    if (comdata == XUNJI_START) {
      follow();
    } else if (comdata == XUNJI_END) {
      motorRun(STOP, 250);
    } else if (comdata == BIZHANG_START) {
      avoidance();
    } else if (comdata == BIZHANG_END) {
      motorRun(STOP, 250);
    } else {
      motorRun(comdata, 250);
    }
    lastCmd = comdata;
    comdata = "";
  } else {
    if (lastCmd == XUNJI_START) {
      Serial.println("现在是 循迹");
      follow();
    } else if (lastCmd == BIZHANG_START) {
      Serial.println("现在是 避障");
      avoidance();
    }
  }
}

void follow()
{
  int data[3];
  data[0] = digitalRead(follow1);
  data[1] = digitalRead(follow2);
  data[2] = digitalRead(follow3);

  //data[x] == 0的时候说明检测到了 黑线
  if (data[0] && data[1] && data[2])//3个都检测到黑线说明 走到了T字  停止
  {
    Serial.println("我stop了现在-");
    motorRun(STOP, 0);
  } else if (!data[0] && data[1] && !data[2] ) { //中间监测到黑线 就直线
    Serial.println("我UP了现在-");
    motorRun(UP, 100);
  } else if (data[0] && !data[1] && !data[2] ) {
Serial.println("我LEFT了现在-");    
    motorRun(LEFT, 180);
  } else if (!data[0] && !data[1] && data[2]) {
    Serial.println("我RIGHT了现在-");
    motorRun(RIGHT, 180);
  } else {
    motorRun(UP, 100);
    Serial.println("不知道干啥-");
  }

  Serial.println("00:" + data[0]);
  Serial.println("---");
  Serial.println("11:" + data[1]);
  Serial.println("---");
  Serial.println("22:" + data[2]);
}

void avoidance()
{
  int pos;
  int dis[3];//距离
  motorRun(UP, xunjiSpeed);
  myServo.write(90);
  dis[1] = getDistance(); //中间
  Serial.println("mid dis:" + dis[1]);
  if (dis[1] < 30)
  {
    motorRun(DOWN,255);
    delay(300);
    motorRun(STOP, 0);
    for (pos = 90; pos <= 150; pos += 1)
    {
      myServo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(10);                       // waits 15ms for the servo to reach the position
    }
    dis[2] = getDistance(); //左边
    Serial.println("left dis:" + dis[2]);
    for (pos = 150; pos >= 30; pos -= 1)
    {
      myServo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(10);                       // waits 15ms for the servo to reach the position
      if (pos == 90)
        dis[1] = getDistance(); //中间
      Serial.println("mid dis:" + dis[1]);
    }
    dis[0] = getDistance(); //右边
    Serial.println("right dis:" + dis[0]);
    for (pos = 30; pos <= 90; pos += 1)
    {
      myServo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(10);                       // waits 15ms for the servo to reach the position
    }
    if (dis[0] < dis[2]) //右边距离障碍的距离比左边近
    {
      //左转
      motorRun(LEFT, 250);
      delay(500);
    }
    else  //右边距离障碍的距离比左边远
    {
      //右转
      motorRun(RIGHT, 250);
      delay(500);
    }
  }
}

int getDistance()
{
  digitalWrite(outputPin, LOW); // 使发出发出超声波信号接口低电平2μs
  delayMicroseconds(2);
  digitalWrite(outputPin, HIGH); // 使发出发出超声波信号接口高电平10μs，这里是至少10μs
  delayMicroseconds(10);
  digitalWrite(outputPin, LOW); // 保持发出超声波信号接口低电平
  int distance = pulseIn(inputPin, HIGH); // 读出脉冲时间
  distance = distance / 58; // 将脉冲时间转化为距离（单位：厘米）
  Serial.println("distance:" + distance); //输出距离值

  if (distance >= 50)
  {
    //如果距离小于50厘米返回数据
    return 50;
  }//如果距离小于50厘米
  else
    return distance;
}


//运动控制函数
void motorRun(String cmd, int value)
{
  analogWrite(leftPWM, value);  //设置PWM输出，即设置速度
  analogWrite(rightPWM, value);
  if (cmd == UP) {
    Serial.println("UP");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == DOWN) {
    Serial.println("DOWN");
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else  if (cmd == LEFT) {
    Serial.println("left");
    analogWrite(leftPWM, value - 90); //设置PWM输出，即设置速度
    analogWrite(rightPWM, value - 70);
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else  if (cmd == RIGHT) {
    Serial.println("right");
    analogWrite(leftPWM, value - 70); //设置PWM输出，即设置速度
    analogWrite(rightPWM, value - 90);
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == LEFT_UP) {
    analogWrite(leftPWM, value - 150); //设置PWM输出，即设置速度
    Serial.println("LEFT_UP");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == LEFT_DOWN) {
    Serial.println("LEFT_DOWN");
    analogWrite(leftPWM, value - 150); //设置PWM输出，即设置速度
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else  if (cmd == RIGHT_UP) {
    analogWrite(rightPWM, value - 150); //设置PWM输出，即设置速度
    Serial.println("RIGHT_UP");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, HIGH);
    digitalWrite(rightMotor1, HIGH);
    digitalWrite(rightMotor2, LOW);
  } else  if (cmd == RIGHT_DOWN) {
    analogWrite(rightPWM, value - 150); //设置PWM输出，即设置速度
    Serial.println("RIGHT_DOWN");
    digitalWrite(leftMotor1, HIGH);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, HIGH);
  } else {
    Serial.println("stop");
    digitalWrite(leftMotor1, LOW);
    digitalWrite(leftMotor2, LOW);
    digitalWrite(rightMotor1, LOW);
    digitalWrite(rightMotor2, LOW);
  }
}

循迹模块的接线，也比较简单，增加了10，11，12号引脚的接入，和蓝牙控制命令

#define XUNJI_START "D201FFFF"

#define XUNJI_END "D202FFFF"

接线

这里可以看到3个循迹的模块，一共9根线，其中每个模块的一个input线就接到arduino对应的引脚号上面，其余的就是电源和地线，接到面包板上面（面包板之前已经讲过原理，不懂的自己查一下）

最后循迹的线可以自己定一下，反正重点就是个T字

循迹
完结

ok! 大功告成 😬

PS:

有些人买的蓝牙型号不一致，只要是BLE就行。

不过如果有些CharacteristicSerial不一致的话，需要修改一下

修改地址

public static final String UUID_SERVICE = “0000ffe0-0000-1000-8000-00805f9b34fb”;

public static final String UUID_INDICATE = “0000000-0000-0000-8000-00805f9b0000”;

public static final String UUID_NOTIFY = “0000ffe1-0000-1000-8000-00805f9b34fb”;

public static final String UUID_WRITE = “0000ffe1-0000-1000-8000-00805f9b34fb”;

public static final String UUID_READ = “3f3e3d3c-3b3a-3938-3736-353433323130”;

里面就有对应的一些特征序列号。如果不知道的话，卖家那里问问，或者手上一些软件可以查看（连上蓝牙，手机上来看特征序列号）

主要就是READ，WRITE，NOTIFY这几个

本图文原图打包下载：0316.rar

方便获取更多学习、工作、生活信息请关注本站微信公众号城东书院 微信服务号城东书院 微信订阅号
来顶一下
返回首页
返回首页
上一篇:什么是“物联网”、“车联网”？ 下一篇:连接万物，创造未来，多角度看物联网技术如何影响我们的生活
推荐内容
高考生入学注意：这些大学不收复读生
高考生入学注意：这些大		【健康】纯净水、天然水、矿泉水、白开水有什么区别？日常喝水怎么选？
【健康】纯净水、天然
14种竞赛生升学路径盘点，原来高考只是你的第15个选择！
14种竞赛生升学路径盘		excel后缀xls和xlsx有什么区别？转换格式难不难？
excel后缀xls和xlsx有
相关内容
栏目更新
栏目热门
关于我们 | 联系我们 | 用户协议 | 广告服务 | 申请链接 | 网站地图 | 版权声明 | 用户留言 | 招聘信息 | 帮助中心 | 社区讨论 | 下载服务
中国文明网传播文明
Copyright ©2019-2024 CDSY Corporation, All Rights Reserved
城东书院® CDSY.XYZ 版权所有 湘ICP备19021508号-1 公安网备案湘公网安备 43102202000103号
※学习、工作、生活信息平台※
本网大部分资源来源于会员上传，除本网组织的资源外，版权归原作者所有，如有侵犯版权，请立刻和本网联系并提供证据，本网将在三个工作日内改正。